### Punctuation symbols
$$include '../../meta/macros.ptl'

import [mix linreg clamp fallback] from "@iosevka/util"

glyph-module

glyph-block Symbol-Punctuation-Bullets : begin
	glyph-block-import CommonShapes
	glyph-block-import Common-Derivatives

	define BulletRadius : Math.max (Width * 2 / 7) [AdviceStroke 3]

	create-glyph 'bullet' 0x2022 : DotAt Middle SymbolMid (BulletRadius - O)

	create-glyph 'triangularBullet' 0x2023 : glyph-proc
		local radius : BulletRadius * 1.5
		local xMid : Middle - radius / 6
		include : spiro-outline
			corner (xMid + radius - O) SymbolMid
			corner (xMid - radius / 2) (SymbolMid - radius / 2 * [Math.sqrt 3])
			corner (xMid - radius / 2) (SymbolMid + radius / 2 * [Math.sqrt 3])

	create-glyph 'whiteBullet' 0x25E6 : glyph-proc
		local s : Math.min [AdviceStroke 5] (BulletRadius * 0.5)
		include : difference
			DotAt Middle SymbolMid (BulletRadius - O)
			DotAt Middle SymbolMid (BulletRadius - O - s)
